home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1990 August / 64er_Magazin_90-08_1990_Markt__Technik_de_Side_A.d64 / leseroutine 2 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  1KB  |  37 lines
  1. 10 rem speedleseroutine fuer alle spuren
  2. 20 rem (c) 1986 by klaus raczek
  3. 30 :
  4. 40 dim r(52): rem feld fuer leseroutine
  5. 50 open1,8,15,"i":rem fehlerkanal oeffnen und initialisieren
  6. 60 print#1,"m-w"chr$(106)chr$(0)chr$(1)chr$(133): rem bei error nicht klappern
  7. 70 fori=0to52
  8. 80 read r(i): rem maschinenprogramm in
  9. 90 next i: rem feld r() einlesen
  10. 100 print"[147]einlesen eines sektors"
  11. 110 input"welche spur (1-40)";sp:r(34)=sp
  12. 120 input"welcher sektor";se:r(38)=se
  13. 130 input"headerspeed";hs:r(6)=hs*32
  14. 140 input"blockspeed";bs:r(23)=bs*32
  15. 150 input"welche id (oder return)";id$
  16. 160 ifid$<>""thenprint#1,"m-w"chr$(18)chr$(0)chr$(2)id$
  17. 170 fori=0to52
  18. 180 print#1,"m-w"chr$(i)chr$(4)chr$(1)chr$(r(i)):rem programm in puffer schreibe
  19. 190 next i
  20. 200 print#1,"m-e"chr$(33)chr$(4):rem programm in puffer ausfuehren
  21. 210 input#1,a,b$,c,d:print:printa;b$;c;d:rem fehlerkanal lesen und zeigen
  22. 220 fori=1to3000:next
  23. 230 :
  24. 240 data173,0,28,41,159,9,0,141,0,28,169,3,133,49,32,16,245,173,0,28,41,159
  25. 250 data9,0,141,0,28,32,86,245,76,212,244,169,24,133,8,169,0,133,9,162,1,134
  26. 260 data249,169,224,32,125,213,76,153,213
  27. 270 :
  28. 280 print"anzeigen des blockinhalts":fori=1to2000:next
  29. 290 rem 256 bytes
  30. 300 :
  31. 310 fori=0to255step16:print"[147]byte      byte      byte"
  32. 320 print"nummer    dezimal   ascii":forj=0to15
  33. 330 print#1,"m-r"chr$(i+j)chr$(3)
  34. 340 get#1,a$:a=asc(a$+chr$(0)):rem eine byte lesen
  35. 350 print""i+j,a,a$"":rem ausgeben: bytenummer, asc-wert, ascii-zeichen
  36. 360 next:print"taste":poke198,0:wait198,1:next
  37.